home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_xemacs.idb / usr / freeware / lib / xemacs-20.4 / lisp / packages / saveplace.el.z / saveplace.el
Encoding:
Text File  |  1998-05-21  |  8.8 KB  |  249 lines
  1. ;;; saveplace.el --- automatically save place in files.
  2.  
  3. ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Karl Fogel <kfogel@cs.oberlin.edu>
  6. ;; Maintainer: FSF
  7. ;; Created: July, 1993
  8. ;; Version: >1.0 (RMS doesn't keep version numbers :-( )
  9. ;; Keywords: bookmarks, placeholders
  10.  
  11. ;; This file is part of XEmacs.
  12.  
  13. ;; XEmacs is free software; you can redistribute it and/or modify it
  14. ;; under the terms of the GNU General Public License as published by
  15. ;; the Free Software Foundation; either version 2, or (at your option)
  16. ;; any later version.
  17.  
  18. ;; XEmacs is distributed in the hope that it will be useful, but
  19. ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21. ;; General Public License for more details.
  22.  
  23. ;; You should have received a copy of the GNU General Public License
  24. ;; along with XEmacs; see the file COPYING.  If not, write to the Free
  25. ;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  26. ;; 02111-1307, USA.
  27.  
  28. ;;; Synched up with: FSF 19.34.
  29.  
  30. ;;; Commentary:
  31.  
  32. ;; Automatically save place in files, so that visiting them later
  33. ;; (even during a different Emacs session) automatically moves point
  34. ;; to the saved position, when the file is first found.  Uses the
  35. ;; value of buffer-local variable save-place to determine whether to
  36. ;; save position or not.
  37. ;;
  38. ;; Thanks to Stefan Schoef, who sent a patch with the
  39. ;; `save-place-version-control' stuff in it.
  40.  
  41. ;;; Code:
  42.  
  43. ;; this is what I was using during testing:
  44. ;; (define-key ctl-x-map "p" 'toggle-save-place)
  45.  
  46. (defgroup save-place nil
  47.   "Automatically save place in files."
  48.   :group 'data)
  49.  
  50.  
  51. (defvar save-place-alist nil
  52.   "Alist of saved places to go back to when revisiting files.
  53. Each element looks like (FILENAME . POSITION);
  54. visiting file FILENAME goes automatically to position POSITION
  55. rather than the beginning of the buffer.
  56. This alist is saved between Emacs sessions.")
  57.  
  58. (defcustom save-place nil
  59.   "*Non-nil means automatically save place in each file.
  60. This means when you visit a file, point goes to the last place
  61. where it was when you previously visited the same file.
  62. This variable is automatically buffer-local.
  63.  
  64. If you wish your place in any file to always be automatically saved,
  65. simply put this in your `~/.emacs' file:
  66.  
  67. \(setq-default save-place t\)"
  68.   :type 'boolean
  69.   :group 'save-place)
  70.  
  71. (make-variable-buffer-local 'save-place)
  72.  
  73. (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  74.   "*Name of the file that records `save-place-alist' value."
  75.   :type 'file
  76.   :group 'save-place)
  77.  
  78. (defcustom save-place-version-control 'nospecial
  79.   "*Controls whether to make numbered backups of master save-place file.
  80. It can have four values: t, nil, `never', and `nospecial'.  The first
  81. three have the same meaning that they do for the variable
  82. `version-control', and the final value `nospecial' means just use the
  83. value of `version-control'."
  84.   :type '(radio (const :tag "Unconditionally" t)
  85.         (const :tag "For VC Files" nil)
  86.         (const never)
  87.         (const :tag "Use value of version-control" nospecial))
  88.   :group 'save-place)
  89.  
  90. (defvar save-place-loaded nil
  91.   "Non-nil means that the `save-place-file' has been loaded.")
  92.  
  93. (defcustom save-place-limit nil
  94.   "Maximum number of entries to retain in the list; nil means no limit."
  95.   :type '(choice (integer :tag "Entries" :value 1)
  96.          (const :tag "No Limit" nil))
  97.   :group 'save-place)
  98.  
  99. (defun toggle-save-place (&optional parg)
  100.   "Toggle whether to save your place in this file between sessions.
  101. If this mode is enabled, point is recorded when you kill the buffer
  102. or exit Emacs.  Visiting this file again will go to that position,
  103. even in a later Emacs session.
  104.  
  105. If called with a prefix arg, the mode is enabled if and only if
  106. the argument is positive.
  107.  
  108. To save places automatically in all files, put this in your `.emacs' file:
  109.  
  110. \(setq-default save-place t\)"
  111.   (interactive "P")
  112.   (if (not buffer-file-name)
  113.       (message "Buffer `%s' not visiting a file" (buffer-name))
  114.     (if (and save-place (or (not parg) (<= parg 0)))
  115.     (progn
  116.       (message "No place will be saved in this file")
  117.       (setq save-place nil))
  118.       (message "Place will be saved")
  119.       (setq save-place t))))
  120.  
  121. (defun save-place-to-alist ()
  122.   ;; put filename and point in a cons box and then cons that onto the
  123.   ;; front of the save-place-alist, if save-place is non-nil.
  124.   ;; Otherwise, just delete that file from the alist.
  125.   ;; first check to make sure alist has been loaded in from the master
  126.   ;; file.  If not, do so, then feel free to modify the alist.  It
  127.   ;; will be saved again when Emacs is killed.
  128.   (or save-place-loaded (load-save-place-alist-from-file))
  129.   (if buffer-file-name
  130.       (progn
  131.         (let ((cell (assoc buffer-file-name save-place-alist)))
  132.           (if cell
  133.               (setq save-place-alist (delq cell save-place-alist))))
  134.         (if save-place
  135.             (setq save-place-alist
  136.           (cons (cons buffer-file-name
  137.                   (if (not (eq major-mode 'hexl-mode))
  138.                   (point)
  139.                 (1+ (hexl-current-address))))
  140.                         save-place-alist))))))
  141.  
  142. (defun save-place-alist-to-file ()
  143.   (let ((file (expand-file-name save-place-file)))
  144.     (save-excursion
  145.       (message "Saving places to %s..." file)
  146.       (set-buffer (get-buffer-create " *Saved Places*"))
  147.       (delete-region (point-min) (point-max))
  148.       (if (file-readable-p file)
  149.           (insert-file-contents file))
  150.       (delete-region (point-min) (point-max))
  151.       (goto-char (point-min))
  152.       (print save-place-alist (current-buffer))
  153.       (let ((version-control
  154.          (cond
  155.           ((null save-place-version-control) nil)
  156.           ((eq 'never save-place-version-control) 'never)
  157.           ((eq 'nospecial save-place-version-control) version-control)
  158.           (t
  159.            t))))
  160.     (write-file file)
  161.     (kill-buffer (current-buffer))
  162.     (message "Saving places to %s...done" file)))))
  163.  
  164. (defun load-save-place-alist-from-file ()
  165.   (if (not save-place-loaded)
  166.       (progn
  167.         (setq save-place-loaded t)
  168.         (let ((file (expand-file-name save-place-file)))
  169.           ;; make sure that the alist does not get overwritten, and then
  170.           ;; load it if it exists:
  171.           (if (file-readable-p file)
  172.               (save-excursion
  173.                 (message "Loading places from %s..." save-place-file)
  174.                 ;; don't want to use find-file because we have been
  175.                 ;; adding hooks to it.
  176.                 (set-buffer (get-buffer-create " *Saved Places*"))
  177.                 (delete-region (point-min) (point-max))
  178.                 (insert-file-contents file)
  179.                 (goto-char (point-min))
  180.                 (setq save-place-alist 
  181.                       (car (read-from-string
  182.                             (buffer-substring (point-min) (point-max)))))
  183.  
  184.         ;; If there is a limit, and we're over it, then we'll
  185.         ;; have to truncate the end of the list:
  186.         (if save-place-limit
  187.             (if (<= save-place-limit 0)
  188.             ;; Zero gets special cased.  I'm not thrilled
  189.             ;; with this, but the loop for >= 1 is tight.
  190.             (setq save-place-alist nil)
  191.               ;; Else the limit is >= 1, so enforce it by
  192.               ;; counting and then `setcdr'ing.
  193.               (let ((s save-place-alist)
  194.                 (count 1))
  195.             (while s
  196.               (if (>= count save-place-limit)
  197.                   (setcdr s nil)
  198.                 (setq count (1+ count)))
  199.               (setq s (cdr s))))))
  200.                 (kill-buffer (current-buffer))
  201.                 (message "Loading places from %s...done" file)
  202.                 t)
  203.             t)
  204.           nil))))
  205.  
  206. (defun save-places-to-alist ()
  207.   ;; go through buffer-list, saving places to alist if save-place is
  208.   ;; non-nil, deleting them from alist if it is nil.
  209.   (let ((buf-list (buffer-list)))
  210.     (while buf-list
  211.       ;; put this into a save-excursion in case someone is counting on
  212.       ;; another function in kill-emacs-hook to act on the last buffer
  213.       ;; they were in:
  214.       (save-excursion
  215.     (set-buffer (car buf-list))
  216.     ;; save-place checks buffer-file-name too, but we can avoid
  217.     ;; overhead of function call by checking here too.
  218.     (and buffer-file-name (save-place-to-alist))
  219.     (setq buf-list (cdr buf-list))))))
  220.  
  221. (defun save-place-find-file-hook ()
  222.   (or save-place-loaded (load-save-place-alist-from-file))
  223.   (let ((cell (assoc buffer-file-name save-place-alist)))
  224.     (if cell
  225.     (progn
  226.       (or after-find-file-from-revert-buffer
  227.           (goto-char (cdr cell)))
  228.       ;; and make sure it will be saved again for later
  229.       (setq save-place t)))))
  230.  
  231. (defun save-place-kill-emacs-hook ()
  232.   ;; First update the alist.  This loads the old save-place-file if nec.
  233.   (save-places-to-alist)
  234.   ;; Now save the alist in the file, if we have ever loaded the file
  235.   ;; (including just now).
  236.   (if save-place-loaded
  237.       (save-place-alist-to-file)))
  238.  
  239. (add-hook 'find-file-hooks 'save-place-find-file-hook t)
  240.  
  241. (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
  242.  
  243. (add-hook 'kill-buffer-hook 'save-place-to-alist)
  244.  
  245. (provide 'saveplace) ; why not...
  246.  
  247. ;;; saveplace.el ends here
  248.  
  249.